【Excel VBA】 ExcelからExcelに差し込み印刷する方法

1⃣同じExcelファイル内に「印刷用のシート」と「差し込みデータ用のシート」を作成します

2⃣「差し込みデータ用のシート」の「A列」に、列「No」を追加します

3⃣「印刷用のシート」に「No」を入力できるセルを作成します

4⃣「印刷用のシート」の「No」を「検索値」にして「VLOOKUP関数」で各データを表示させます

※下図の上側が「印刷用のシート」、下側が「差し込みデータ用のシート」です

④画面右側のチェックボックス「開発」にチェックを入れます

⑤画面右下のボタン「OK」をクリックします

※この操作により、メニュー「開発」が表示されるようになります

※別のウインドウが開きます

⑧プルダウンメニューの「標準モジュール」をクリックします

※この操作により、画面左側のツリーに「標準モジュール」が追加されます

⑩画面右側の空白部分に、下記コードをすべてコピー＆ペーストします

※印刷の際は、コード内の「★」で囲まれた部分を修正してご利用ください

Sub 差し込み印刷()
        
    '宣言
    Dim rc As VbMsgBoxResult
    Dim strName1 As String
    Dim strName2 As String
    Dim strKey As String
    Dim lngStart As Long
    Dim lngEnd As Long
    Dim i As Long
    
    
'★★★★★★ 差し込み印刷設定（ここから）★★★★★★★★★★★★★★★★★★★★★
    
    '「印刷するシート名」をダブルクォーテーションの中に入力
    strName1 = "Sheet1"
    
    '「差し込みデータのシート名」をダブルクォーテーションの中に入力
    strName2 = "Sheet2"
    
    'VLOOKUP関数の「検索値が入力されているセル」をダブルクォーテーションの中に入力
    strKey = "D2"
    
    '差し込み印刷するデータの「開始行」を入力
    lngStart = 2
    
    '差し込み印刷するデータの「終了行」を入力
    lngEnd = 6
        
'★★★★★★ 差し込み印刷設定（ここまで）★★★★★★★★★★★★★★★★★★★★★
    
   
    '確認メッセージを表示
    rc = MsgBox("処理を続行しますか？", vbYesNo + vbQuestion)
    
    '差し込み印刷を実行
    If rc = vbYes Then
               
        '開始行から終了行まで繰り返し印刷
        For i = lngStart To lngEnd
            
            'Noの更新
            ThisWorkbook.Worksheets(strName1).Range(strKey).Value = ThisWorkbook.Worksheets(strName2).Range("A" & i).Value
            
            '印刷
            ThisWorkbook.Worksheets(strName1).PrintOut Copies:=1, Collate:=True
                                   
        Next i
                
        MsgBox "差し込み印刷が完了しました", vbInformation
    
    '差し込み印刷を中止
    Else
    
        MsgBox "差し込み印刷を中止しました", vbInformation
    
    End If

End Sub

⑫画面右上の「✖」をクリックして閉じます

⑭フォームコントロールの「ボタン」をクリックします

※描いた四角が「ボタン」になります

⑰画面右下のボタン「OK」をクリックします